'-----------------------------------------------------------------
'			TestHTTPGet.vbs
' This script retrieves a simple html page from the web, analyses
' it looking for <img src=... tags. Pictures are then loaded,
' saved to disk and added to the current album.
' Notes:
'   - The URL of the "src=" should be relative to the one of the
'     html page.
'   - The parsing of the html page is very limited in this demo.
'-----------------------------------------------------------------
Option Explicit
app.cleartrace

dim sURL, sBaseUrl, sDestFolder
sUrl = "http://www.liberation.fr/"
'sUrl = "http://perso.wanadoo.fr/myalbum/MyAlbum.html"
'sUrl = "http://www.google.com/"
sBaseUrl = left( sUrl, instrrev(sUrl,"/") )
sDestFolder = "d:\temp\"

dim alb, pic, s, sL, k, k2, sFile, sDestFile, bOK
set alb = app.GetCurrentAlbum
app.Trace "Retrieving html page '" & sUrl & "'..."
s = app.HTTPGetString( sUrl )
sL = LCase(s)

bOK = True
k = 1
while (bOK)
  k = instr( k, sL, "<img" )
  if (k > 0) then
    k = instr( k+4, sL, "src=" )
    sFile = ""
    k = k + 4
    if mid(s,k,1) = """" then
      k = k+1
      k2 = instr( k, s, """" )
      if k2 > 0 then sFile = mid(s, k, k2-k)
    else
      k2 = instr( k, s, " " )
      if k2 > 0 then sFile = mid(s, k, k2-k)
    end if
    if sFile <> "" then
      k2 = instrrev( sFile, "/" )
      if k2 > 0 then sDestFile = mid( sFile, k2 + 1 )
      set pic = alb.GetPictureByFileName( sDestFile )
      if pic is nothing then
	sDestFile = sDestFolder & sDestFile
	app.Trace "Picture found: " & sBaseUrl & sFile & " --> " & sDestFile
	if app.HTTPGet( sBaseUrl & sFile, sDestFile ) = 0 then
	  alb.AddPicture sDestFile
	  alb.Redraw
	end if
      else
	app.Trace "Picture alrealy found: " & sDestFile
      end if      
    end if
  else
    bOK = False
  end if
wend
app.Trace "Done !"